cogier	11,637
gbWilly	11,435
Poly	5,872
sholzy	3,737
Quincunxian	3,559

S	M	T	W	T	F	S
1	2	3	4	5	6	7
8	9	10	11	12	13	14
15	16	17	18	19	20	21
22	23	24	25	26	27	28
29	30	31

Scrolling text effect

Post

Posted December 5th 2025, 12:17 AM

Rating:

(

)

#1 (In Topic #1939)

Yogi

Enthusiast

with ScrollView

Hi Folks,

I would like to share a topic: vertical ticker text

and at the same time ask what could be improved.

In Gambas at the beginning, there is ‘About’, which features vertical ticker text with images
using a gridview. I looked at the source code and couldn't quite figure it out.

So I programmed a simpler version based on a ‘Scrollview’ and a ‘Textlabel’ object used
in a modul.

Here is the result and if you know a simple and better way to mix Text and Images,
let me know. Magic word "simple" 🙂

Code (`gambas`)

Public Sub btnAbout_Click()
Dim s As String
s = File.Load("./loremIpsum.txt")
LFAbout.ShowAbout("Linux/Ubuntu/Gambas", s, 500, 300)
End

The sub takes the window title
a string to be shown
and optional arguments width and heigth of the window

It creates a new window with a scrollview and a textlabel object and a "OK" button.
Usage if the windows is shown (it is modal)

Mouse over the Scrolling Text:
Left Mouse Down … Scroll faster forward
Right Mouse Down … Scroll faster backward
ESC key or OK Button => quit

No special "bells and whistles", formatting the text you can use the HTML subset for a textlabel.

Bildschirmfoto vom 2025-12-05 06-10-51.png — Image

Bildschirmfoto vom 2025-12-05 06-11-04.png — Image

Attachment

LFScrollAbout-0.0.1.tar.gz

Regards,
Yogi

https://hilfe-selbsthilfe.at
https://yoga-der-mitte.info

Post

Posted December 5th 2025, 8:35 AM

Rating:

(

)

cogier

Guru

cogier is in the usergroup ‘GambOS Contributor’

Yogi said

Magic word "simple" 🙂

Ok, this version does not scroll past the top and therefore is not endless, but is very simple :thumbs:

. You will need to add your "loremIpsum.txt" file to the program.

Code (`gambas`)

Private TextLabelDisplay As TextLabel
Private aSpring As Spring
Private Timer1 As Timer
 
Public Sub Form_Open()
  
  With Me
    .Padding = 5
    .Arrangement = Arrange.Vertical
    .H = 700
    .W = 415
    .Y = 50
  End With
  
  aSpring = New Spring(Me)
  
  TextLabelDisplay = New TextLabel(Me) As "TextLabelDisplay"
  TextLabelDisplay.Text = File.Load(Application.Path &/ "loremIpsum.txt")
  
  Timer1 = New Timer As "Timer1"
  Timer1.Delay = 25
  Timer1.Start
  
End
 
Public Sub Timer1_Timer()
  
  Inc TextLabelDisplay.H
  
End

Post

Posted December 5th 2025, 10:21 AM

Rating:

Yogi

Enthusiast

cogier said

Ok, this version does not scroll past the top and therefore is not endless, but is very simple . You will need to add your "loremIpsum.txt" file to the program.

Code (gambas)

Private TextLabelDisplay As TextLabel

Private aSpring As Spring

Private Timer1 As Timer

Public Sub Form_Open()

With Me

.Padding = 5

.Arrangement = Arrange.Vertical

.H = 700

.W = 415

.Y = 50

End With

aSpring = New Spring(Me)

TextLabelDisplay = New TextLabel(Me) As "TextLabelDisplay"

TextLabelDisplay.Text = File.Load(Application.Path &/ "loremIpsum.txt")

Timer1 = New Timer As "Timer1"

Timer1.Delay = 25

Timer1.Start

End

Public Sub Timer1_Timer()

Inc TextLabelDisplay.H

End

From “Post #13,313”, December 5th 2025, 8:35 AM

cogier ,

Wow, a really short one.
Thanks for sharing 👍

Regards,
Yogi

https://hilfe-selbsthilfe.at
https://yoga-der-mitte.info

Post

Posted December 7th 2025, 6:50 AM

Rating:

Yogi

Enthusiast

It wouldn't leave me alone, so I played around with the FAbout class from the Gambas source code.

Spoiler: I still don't have a clear understanding of what exactly is going on there.

I tried to gain a little more clarity by changing the background colour of the objects used
and lo and behold, there is a small visual error that is almost imperceptible.

But see for yourself, I simply added to and expanded the source code, removed the original
Authors and replaced with "LoremIpsum":

Code (`gambas`)

' Gambas class file
 
Private $aCache As Image[]
Private $Y As Integer
Private $YP As Integer
Private $bPressed As Boolean
Private $bLeftMouse As Boolean
Private $iGap As Short = 2
 
Static Public Sub Run()
 
  FAbout.ShowModal
 
End
 
Public Sub _new()
 
  Me.Background = Color.Opacity(Color.Background, 1)
  gvwAbout.NoAnimation = True
 
End
 
 
Public Sub Form_Open()
 
 
End
 
 
Public Sub btnClose_Click()
 
  Me.Close
 
End
 
 
 
 
Private Sub FillAbout()
 
 
  Dim sText, sFont As String
  Dim aAuthor As New String[]
  Dim I As Integer
  Dim N As Integer
  Dim aText As String[]
 
  sText = Replace(File.Load("./loremIpsum.txt"), "<br>", gb.NewLine)
  aText = Split(sText, gb.NewLine)
  For I = 0 To aText.Count - 1
    aAuthor.Add(aText[I])
  Next
 
  gvwAbout.Columns.Count = 1
  N = 6
  
  gvwAbout.Rows.Count = aAuthor.Count + N + 2
  gvwAbout.Columns[0].Width = Me.ClientWidth - Desktop.Scale * 6
  gvwAbout.Padding = 0
  
  ' Space
  gvwAbout.Rows[0].H = dwgAbout.H / 2
  ' Gambas
  gvwAbout[1, 0].RichText = "<b>G</b>ambas <b>A</b>lmost<br><b>M</b>eans <b>BAS</b>ic !"
  gvwAbout[1, 0].Font = Font["+10,Spacing=2"]
  gvwAbout[1, 0].Alignment = Align.Top
  'gvwAbout[1, 0].WordWrap = True
  ' Logo
  gvwAbout[2, 0].Picture = Picture["icon:/128/gambas"]
  gvwAbout[2, 0].Alignment = Align.Top
 
  For I = 1 To 5
    gvwAbout.Rows[I].H = -1
  Next
  gvwAbout.Rows[4].H += Desktop.Scale * 2
  
 
  
  For I = 0 To aAuthor.Max
  
    sText = aAuthor[I]
    gvwAbout[N, 0].WordWrap = True
    gvwAbout[N, 0].RichText = sText
    gvwAbout[N, 0].Padding = Desktop.Scale 
    gvwAbout[N, 0].Alignment = Align.Center
    
    If I > 7 Then 
      sFont = "12"
    Else 
      sFont = "+" & Str(i)
    Endif 
    
    gvwAbout[N, 0].Font = Font[sFont]
    gvwAbout.Rows[N].Height = -1
    Inc N
  
  Next
 
  Inc N
 
  gvwAbout[N, 0].Picture = Picture["./ende.jpg"]
  gvwAbout[N, 0].Alignment = Align.Top
  gvwAbout.Rows[N].Height = -1
 
  Inc N
 
 
  gvwAbout.Rows[N].H = dwgAbout.H
 
End
 
Private Sub ScrollText(D As Integer)
 
  Dim hImage As Image
  
  If $bLeftMouse = True And $bPressed Then 
    D = -D
  Endif
  
  $Y += D
 
  If D > 0 Then
    
    While $Y >= dwgAbout.H 
      
      $Y -= dwgAbout.H
      
      hImage = $aCache[0]
      $aCache[0] = $aCache[1]
      $aCache[1] = $aCache[2]
      $aCache[2] = hImage
      
      Inc $YP
      If ($YP * dwgAbout.H) >= (gvwAbout.ScrollH - dwgAbout.H) Then $YP = 0
  
      PaintAbout($aCache[2], $YP)
      
    Wend
 
  Else If D < 0 Then
    
    While $Y < 0 
 
      If $YP = 2 Then
        $Y = 0
        Break
      Endif
      
      $Y += dwgAbout.H - 5
      
      hImage = $aCache[2]
      $aCache[2] = $aCache[1]
      $aCache[1] = $aCache[0]
      $aCache[0] = hImage
      
      Dec $YP
      If $YP < 0 Then $YP = gvwAbout.ScrollH \ dwgAbout.H - 1
      PaintAbout($aCache[0], $YP - 2)
      
    Wend
 
  Endif
  
  dwgAbout.Refresh
  
End
 
Public Sub timAbout_Timer()
 
  ScrollText(If($bPressed, 16, 1))
 
End
 
Public Sub dwgAbout_Draw()
 
  Paint.DrawImage($aCache[0], 0, -$Y)
  If $Y > 0 Then Paint.DrawImage($aCache[1], 0, dwgAbout.H - $Y)
  
End
 
Public Sub Form_KeyPress()
 
  If Key.Code = Key.Escape Then Me.Close
 
End
 
Private Sub PaintAbout(hImage As Image, iPos As Integer)
 
  gvwAbout.Move(Me.ClientW, 0, dwgAbout.W + $iGap, dwgAbout.H + $iGap) 'changed to +2, if not there is a visible gap
  If iPos < 0 Then iPos += gvwAbout.ScrollH \ dwgAbout.H 
  gvwAbout.Scroll(0, iPos * dwgAbout.H)
  hImage.Fill(Color.Transparent)
  Paint.Begin(hImage)
  Paint.ClipRect = Rect(0, 0, dwgAbout.W, dwgAbout.H)
  gvwAbout.ScrollArea_Draw
  Paint.End
 
End
 
Public Sub Form_Arrange()
 
  Dim I As Integer
  
  FillAbout
  
  $aCache = New Image[3]
  
  For I = 0 To $aCache.Max
    $aCache[I] = New Image(dwgAbout.W, dwgAbout.H)
    PaintAbout($aCache[I], I)
  Next
  $YP = 2
  
End
 
Public Sub dwgAbout_MouseDown()
 
  $bPressed = True
  If Mouse.State = 4 Then 
    $bLeftMouse = True
  Else 
    $bLeftMouse = False
  Endif
End
 
Public Sub dwgAbout_MouseUp()
 
  $bPressed = False
 
End
 
Public Sub dwgAbout_MouseWheel()
 
  Dim I As Integer
 
  For I = 1 To 32
    ScrollText(If(Mouse.Forward, -2, 2))
    Wait
  Next
 
End
 
Public Sub ToggleButton1_Click()
 
  If ToggleButton1.Value Then 
    ToggleButton1.Text = "Remove Gap"
    $iGap = 0
  Else 
    ToggleButton1.Text = "Show Gap"
    $iGap = 2
  Endif
  Form_Arrange()
  dwgAbout.Refresh
 
End
 

Attachment

welcomeabout-0.0.1.tar.gz

https://hilfe-selbsthilfe.at
https://yoga-der-mitte.info

1 guest and 0 members have just viewed this.

Not logged in

Leader-board

Scrolling text effect

Post

with ScrollView

Code (`gambas`)

Post

Yogi said

Code (`gambas`)

Post

cogier said

Code (`gambas`)

Post

Code (`gambas`)

Statistics

Not logged in

Leader-board

Scrolling text effect

Post

with ScrollView

Code (gambas)

Post

Yogi said

Code (gambas)

Post

cogier said

Code (gambas)

Post

Code (gambas)

Statistics

Code (`gambas`)

Code (`gambas`)

Code (`gambas`)

Code (`gambas`)